int NUM_DROPS = 25;
int maxD = 150;
int BACKGROUND = 100;
int Current_DROP = 0;

Drop[] nDrop = new Drop [NUM_DROPS];

void setup(){
  size(500,500);
  noFill();
  ellipseMode(CENTER);
  smooth();  
  for (int i = 0; i<nDrop.length; i++){
    nDrop[i] = new Drop();
  } 
}



void draw(){
  background(BACKGROUND);
  for (int i = 0; i<nDrop.length; i++){
    nDrop[i].grow();
    nDrop[i].plot();
  }
  if (frameCount % (maxD/NUM_DROPS) == 0) { 
    nDrop[Current_DROP].newDrop();
    Current_DROP++;
    if (Current_DROP>=NUM_DROPS){
      Current_DROP = 0;
    }
  }

}



class Drop{
  float x;
  float y;
  float d;
  float F;

  Drop (){                  //constructor: initial drops are out of sight
    x = -width;
    y = -height;
    d = 1;
    F = 255;
  }

  void newDrop(){          //redefine the drops
    x = random(0,width);
    y = random(0,height);
    d = 0;
    F = 255;
  }

  void grow (){
    d = d + 1; 
    F = F - (255-BACKGROUND)/maxD;
  }  

  void plot(){
    stroke (F,100);
    ellipse(x,y,d,d);
  }

}