//charles valla-
//space packing 01

int NUM_CIRCLES = 23;
int DIAM = 50;
circle[] nCircle;



void setup(){
  
  size (500,500);
  background (0);
  fill (255,100);
  smooth();
  ellipseMode(CENTER);
  
  nCircle = new circle[NUM_CIRCLES];
  for (int i=0; i<nCircle.length; i++){
    nCircle[i] = new circle (random (0,width),random (0,height),DIAM);
  } 
  
}




void draw(){
  background (200); 
  for (int i=0; i<nCircle.length; i++){
    stroke(0);
    nCircle[i].render();
    nCircle[i].moveIN(3); 
    nCircle[i].moveOUT();
    stroke(150,100);
    nCircle[i].links();
  } 
}




void mouseClicked(){
  background (255);
  for (int i=0; i<nCircle.length; i++){
   nCircle[i] = new circle (random (0,width),random (0,height),50);
  }
}




class circle{
  float x;
  float y;
  float D; 
  
  circle (float inX, float inY, float inDiameter){
    x = inX;
    y = inY;
    D = inDiameter;
  }
    
  void render (){
    ellipse (x,y,D,D);
  }
        
  void moveIN (float rate){
    for (int i=0; i<nCircle.length; i++){
      x = x + (nCircle[i].x-x)/(pow(10,rate));
      y = y + (nCircle[i].y-y)/(pow(10,rate));
    }
  } 
   
  void moveOUT (){   
    float Vx, Vy, d;
    for (int i=0; i<nCircle.length; i++){
      d = dist(nCircle[i].x, nCircle[i].y,x,y);
      Vx = (D-d)/D*(nCircle[i].x-x);
      Vy = (D-d)/D*(nCircle[i].y-y);   
      if ( d < D ){
         x = x - Vx;
         y = y - Vy;
      }
    } 
  }
   
  void links (){
    float d;
    for (int i=0; i<nCircle.length; i++){
      d = dist(nCircle[i].x, nCircle[i].y,x,y);
      if (d < D+D/2){
        line (nCircle[i].x, nCircle[i].y,x,y);
      }
    }
  }
    
    
}